Call pcopen() on groups of points dynamically?

[joulejang2012]

Hey everyone! First time posting

I have a variable number of groups of points, and I want each point to find its nearest neighbor in every group that is not its own. I know pcopen() takes in either an Opinput or a filename, so I was wondering if there is a way to somehow dynamically set inputs to take in groups or if there is a way to export groups of points to a file without manually having to delete non-selected on each group and exporting them individually with the file sop.

[f1480187]

If groups don't overlap, convert groups to name attribute using Name node and then use nearpoint function:

// Point wrangle.

i@near = nearpoint(0, "!" + s@pt_group_name, @P);

// Test.
int prim = addprim(0, "polyline");
addvertex(0, prim, @ptnum);
addvertex(0, prim, @near);

 

Effect is pretty nice on clustered geo.

 

exclude_itself_group.hipnc

[joulejang2012]

Is there no way to do this using point clouds?

[f1480187]

Here is pcfind signature accepting a group. I think it is an equivalent of the nearpoints function, which also return an array.

int [] pcfind(int inputnum, string ptgroup, string Pchannel, vector P, float radius, int maxpoints);

If you really meant pure VEX solution, without converting stuff, use something like this:

// Point wrangle.

string groups[] = detailintrinsic(0, "pointgroups");

foreach (string group; groups)
{
    if (inpointgroup(0, group, @ptnum))
    {
        i@near = pcfind(0, "!" + group, "P", @P, 1e10, 1)[0];

        // Test.
        int prim = addprim(0, "polyline");
        addvertex(0, prim, @ptnum);
        addvertex(0, prim, @near);

        // Exit loop.
        break;
    }
}

It will act similar. Just a bit more code.

 

exclude_itself_group_pcloud.hipnc

Edited August 21, 2016 by f1480187