Ray SOP ignore backfaces

[Rikrok]

Is there any way for the ray sop to register a hit only on the front face of a primitive and pass through backfaces?

[Atom]

Have you tried setting the Ray Combiner to "Shortest" ray?

[Rikrok]

Have you tried setting the Ray Combiner to "Shortest" ray?

 

That doesn't work (and I wouldn't expect it to, it's not how shooting multiple rays works).

[anim]

you probably can't do that in Ray SOP

but you can use intersect_all() VEX function or VOP to get all intersections along the line, then check in for loop for first one that is not back facing

Edited September 30, 2015 by anim

[acey195]

Alternatively you can extract the hit normal and do a dot check against the the initial point normals (if dot is larger than 0, it is a backface)

and if needed, you could start a new ray at this point to check for subsequent front/backfaces

[Fake Pilot]

Is it possible to write a VEX example of this? :-)

[Fake Pilot]

Did it myself. Works.

vector dir = v@N*1000;
vector pos;
vector uvw;

int hit_prim = intersect(@OpInput2, @P, dir, pos, uvw);
v@primN = prim_normal(1,hit_prim,uvw);

if(dot(@primN,@N) < 0){
	@P = pos;
}

 

[anim]

if you want your ray to continue through all backfaces and hit something behind you'd need to do something along the lines suggested in previous posts

vector t = chv("t");
vector dir = normalize(chv("dir"));
float maxlength = chf("maxlength");

// get all intersection
int prims[];
vector hitPs[], primuvs[];
intersect_all(1, t, dir*maxlength, hitPs, prims, primuvs, .001, .001);

// filter out backface intersections and stop at first frontface
vector outP = t + dir*maxlength;
foreach(int i; vector hitP; hitPs){
    int prim = prims[i];
    vector primuv = primuvs[i];
    vector hitN = primuv(1, "N", prim, primuv);
    
    float dot = dot(dir, hitN);
    if (dot < 0){
        outP = hitP;
        break;
    }
}

// create line
int pt0 = addpoint(0, t);
int pt1 = addpoint(0, outP);
addprim(0, "polyline", pt0, pt1);

 

ts_intersect_ignore_backfaces.hip

Edited January 10, 2020 by anim